home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Collection of Tools & Utilities
/
Collection of Tools and Utilities.iso
/
dskut
/
hdsource.zip
/
HDRW.ASM
< prev
next >
Wrap
Assembly Source File
|
1986-02-24
|
11KB
|
296 lines
PAGE 64,132 ;PAGE WIDTH,LENGTH
.SALL
TITLE PC/AT DIAGNOSTIC - WRITE/READ/VERIFY TEST
; **********************************************************************
; * *
; * MODULE NAME HDRW *
; * AUTHOR JIM BRACKING *
; * *
; * DECSRIPTION THIS PROGRAM PERFORMS THE FOLLOWING *
; * FUNCTIONS: *
; * *
; * 1. WRITES, THEN VERIFIES THE DATA ON THE *
; * ENTIRE DIAGNOSTIC CYLINDER. *
; **********************************************************************
;
; **********************************************************************
; * EXTERNAL PROGRAM REFERENCES *
; **********************************************************************
EXTRN SCRMGR:NEAR
; **********************************************************************
; * EXTERNAL DATA REFERENCES *
; **********************************************************************
INCLUDE HDDATA.ASM
; **********************************************************************
; * EXTERNAL SUBROUTINE REFERENCES *
; **********************************************************************
INCLUDE HDSUB.ASM
; **********************************************************************
; * PUBLIC DECLARES *
; **********************************************************************
PUBLIC HDRW
; **********************************************************************
; * MACROS *
; **********************************************************************
;
IF1
INCLUDE HD.MAC
INCLUDE \SCRMGR\SCRNWORK.MAC
ENDIF
; **********************************************************************
; * *
; * BEGIN *
; * *
; **********************************************************************
CSEG SEGMENT PARA PUBLIC 'CODE'
ASSUME CS:CSEG
HDRW PROC NEAR
ASSUME DS:CSEG ;DATA SEGMENT
JMP BY_ID ;JMP AROUND ID
ID HDRW
INCLUDE \SCRMGR\SCRNWORK.ASM
; **********************************************************************
; * EQUATES AND STRUCTURES *
; **********************************************************************
INCLUDE HDEQU.ASM
; **********************************************************************
; * SCREENS *
; **********************************************************************
;
SFIELD X00,X01,,@LABEL,RV,23,02,'CTRL-F1 TO START'
SFIELD X01,X02,,@LABEL,RV,23,29,'ESC FOR THE MAIN MENU'
SFIELD X02,X00,,@LABEL,RV,23,62,'CTRL-BRK TO STOP'
;
SFIELD XI0,XI1,,@LABEL,LO,19,05,'DRIVE =>'
SFIELD XI1,XI2,1,@EX+@NUM+@UC+@NFULL+@REQ,LO,19,14
SFIELD XI2,XI3,,@LABEL,LO,20,05,'(1 OR 2)'
SFIELD XI3,XI4,,@LABEL,LO,19,20,'RUN CONTINIOUSLY =>'
SFIELD XI4,XI5,1,@UC+@EX+@YN+@NFULL+@REQ,LO,19,40
SFIELD XI5,XI0,,@LABEL,LO,20,26,'(Y OR N)'
;
SFIELD XS0,XS1,,@LABEL,LO,19,46,'STATUS =>'
SFIELD XS1,XS0,,@LABEL,LO,19,56,'** IDLE ** '
;
SFIELD XS2,XS3,,@LABEL,LO,19,46,'STATUS =>'
SFIELD XS3,XS2,,@LABEL,HI,19,56,'** WORKING **'
;
SFIELD XC0,XC1,,@LABEL,LO,20,46,'CYLINDER =>'
SFIELD XC1,XC0,04,@LABEL,LO,20,58
;
SFIELD XE0,XE1,,@LABEL,LO,21,46,'ERRORS =>'
SFIELD XE1,XE0,05,@LABEL,LO,21,56
;
SFIELD T05,T05,,@LABEL,RV,17,28,'WRITE/READ/VERIFY TEST'
;
BY_ID:
HDRW ENDP
; *********************************************************************
; * *
; * WRITE/VERIFY TEST *
; * *
; *********************************************************************
RWV PROC
CLS LO,4,1,23,78 ;CLEAR THE SCREEN
BOX 17,0,08,80,LO ;OUTLINE
WRITEC 0CCH,LO,17,0,1 ; THE
WRITEC 0B9H,LO,17,79,1 ; SCREEN
WRITE T05 ;TYPE OF TEST
WRITE X00 ;COMMANDS
RWV_00:
WRITE XS0 ;STATUS
LEA BX,XI1 ;DRIVE ENTRY
MOV [BX].S_ATTR,LO ;RESTORE ATTRIBUTE
CMP ALL_SW,0FFH ;RUN ALL TEST??
JE RWV_01 ;YES
MOV [BX].S_DATA,' ' ;CLEAR DRIVE
JMP RWV_01A ;CONTINUE
RWV_01:
LEA BX,XI4 ;Y/N ENTRY
MOV [BX].S_ATTR,LO ;RESTORE ATTRIBUTE
MOV [BX].S_DATA,'Y' ;DEFAULT NO
MOV AL,DR ;FETCH DRIVE
INC AL ;NUMBER
OR AL,30H ;MAKE IT A NUMBER
MOV [BX].S_DATA,AL ;SET IT IN THE MSG
WRITE XI0 ;DRIVE
JMP RWV_15 ;CONTINUE
RWV_01A:
LEA BX,XI4 ;Y/N ENTRY
MOV [BX].S_ATTR,LO ;RESTORE ATTRIBUTE
MOV [BX].S_DATA,'N' ;DEFAULT NO
WRITE XI0 ;DRIVE
RWV_02:
READR BX ;FETCH DRIVE
CALL TRANS_KEY ;TRANSLATE THE KEY
JNC RWV_04 ;SUCESSFULL
RWV_03:
CALL BEEP ;RING THE BELL
JMP RWV_02 ;TRY AGAIN
RWV_04:
CMP AL,ESC_KEY ;ESCAPE KEY??
JNE RWV_05 ;NO
JMP EXIT ;RETURN
RWV_05:
CMP AL,C_BRK ;CONTROL BREAK KEY??
JNE RWV_07 ;NO
JMP RWV ;YES - START OVER
RWV_07:
CMP AL,C_F1 ;CTRL_F1??
JNE RWV_03 ;NO - INVALID KEY
LEA BX,XI1 ;DRIVE ENTRY
MOV [BX].S_ATTR,LO ;RESTORE ATTRIBUTE
MOV AL,[BX].S_DATA ;FETCH DRIVE NUMBER
CMP AL,'1' ;VALID DRIVE??
JE RWV_08 ;YES
CMP AL,'2' ;VALID DRIVE??
JE RWV_08 ;YES
MOV [BX].S_ATTR,HI ;HIGHLIGHT IT
PMSG 22 ;DISPLAY THE MESSAGE
CALL BEEP ;RING THE BELL
WRITE XI0 ;DRIVE + INTERLEAVE
JMP RWV_02 ;TRY AGAIN
RWV_08:
AND AL,0FH ;ADJUST
DEC AL ; DRIVE NUMBER
CMP AL,NUM_DR ;DRIVE INSTALLED
JB RWV_10 ;YES
MOV [BX].S_ATTR,HI ;HIGHLIGHT IT
PMSG 21 ;DISPLAY THE MESSAGE
CALL BEEP ;RING THE BELL
WRITE XI0 ;DRIVE + INTERLEAVE
JMP RWV_02 ;TRY AGAIN
RWV_10:
MOV DR,AL ;SAVE DRIVE NUMBER
LEA BX,XI1 ;DRIVE ENTRY
MOV [BX].S_ATTR,LO ;RESTORE ATTRIBUTE
WRITE XI0 ;DRIVE
RWV_15:
MOV AX,06DB6H ;DATA PATTERN
MOV CX,256 ;NUMBER OF WORDS
CLD ;FORWARD DIRECTION
LEA DI,DATA_BUF ;OUTPUT
PUSH CS ;ESTABLISH
POP ES ; SEGMENT
REP STOSW ;FILE THE BUFFER
RWV_20:
CALL READ_PARMS ;FETCH DRIVE PARMS
MOV CUR_HD,0 ;INITIALIZE
MOV CUR_SEC,1 ; THE
MOV CUR_CYL,0 ; STARTING FIELDS
MOV BAD_SEC,0 ;CLEAR THE BAD TRK COUNT
MOV ERR_CNT,0 ;CLEAR THE ERROR COUNT
MOV NUM_SEC,1 ;NUMBER OF SECTORS
CALL UPD_CYL ;DISPLAY CYLINDER NUMBER
CALL UPD_ERR ;DISPLAY ERROR COUNT
WRITE XS2 ;STATUS
CLS LO,4,2,16,78 ;CLEAR THE SCREEN
CALL HIDE_CUR ;HIDE THE CURSOR
; *********************************************************************
; * BEGIN THE TEST *
; *********************************************************************
CALL CTLR_DIAG ;EXECUTE CTLR HDNOSTICS
JNC RWV_30 ;SUCESSFULL
PMSG 32,HI ;FAILED
MOV RW_X,32 ;SET CODE
CALL UPD_ERR ;DISPLAY ERROR COUNT
CMP ALL_SW,0FFH ;RUN ALL TEST??
JE RWV_28 ;YES
JMP RWV_00 ;TERMINATE FORMAT
RWV_28:
JMP EXIT ;EXIT
RWV_30:
PUSH DS ;ESTABLISG
POP ES ; SEGMENT
MOV AX,MAX_CYL ;POINT TO
MOV CUR_CYL,AX ; HD CYLINDER
LEA BX,DATA_BUF ;BUFFER
PUSH DS ;ESTABLISH
POP ES ; SEGMENT
RWV_40:
MOV AH,0BH ;CHECK FOR
INT 21H ; CONTROL BREAK
CALL UPD_CYL ;DISPLAY CURRENT CYLINDER
RWV_45:
MOV HD_CMD,WR_CMD ;WRITE COMMAND
MOV NUM_SEC,1 ;NUMBER OF SECTORS
CALL EXEC_CMD ;WRITE THE SECTOR
JNC RWV_50 ;SUCESSFULL
CMP AL,0FFH ;CTLR BROKE??
JE RWV_79 ;YES
CALL UPD_ERR ;DISPLAY ERROR COUNT
CALL NEXT_SEC ;TRY ALL SECTORS ON